blob: d9b6dce1f29f386cc43c9fd9b709eb3d8393bee4 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
<?xml version="1.0" encoding="ISO-8859-1" ?>
<!DOCTYPE xsl:stylesheet PUBLIC "-//FreeBSD//DTD FreeBSD XSLT 1.0 DTD//EN"
"http://www.FreeBSD.org/XML/www/share/sgml/xslt10-freebsd.dtd" [
<!ENTITY title "FreeBSD News Flash">
<!ENTITY link "http://www.FreeBSD.org/news/">
<!ENTITY email "freebsd-www">
<!ENTITY realname "Webmaster Team">
]>
<!-- $FreeBSD$ -->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
xmlns:cvs="http://www.FreeBSD.org/XML/CVS"
exclude-result-prefixes="cvs">
<xsl:import href="http://www.FreeBSD.org/XML/www/lang/share/sgml/libcommon.xsl"/>
<xsl:output method="xml" indent="yes" encoding="&xml.encoding;"/>
<!-- Generate the main body of the RDF file -->
<xsl:template match="news">
<rss version="2.0" xmlns:atom="http://www.w3.org/2005/Atom">
<channel>
<title>&title;</title>
<link>&link;</link>
<description>News from the FreeBSD Project</description>
<language>en-us</language>
<webMaster>&email;@FreeBSD.org (&realname;)</webMaster>
<managingEditor>&email;@FreeBSD.org (&realname;)</managingEditor>
<docs>http://blogs.law.harvard.edu/tech/rss</docs>
<ttl>120</ttl>
<image>
<url>http://www.FreeBSD.org/logo/logo-full.png</url>
<title>&title;</title>
<link>&link;</link>
</image>
<atom:link href="&link;rss.xml" rel="self" type="application/rss+xml" />
<!-- Only include the last 10 events -->
<xsl:apply-templates select="descendant::event[position() <= 10]"/>
</channel>
</rss>
</xsl:template>
<!-- Generate the <item> elements and their content -->
<xsl:template match="event">
<xsl:param name="year" select="../../../name" />
<xsl:param name="month" select="../../name" />
<xsl:param name="day" select="../name" />
<xsl:param name="this" select="." />
<xsl:param name="pos">
<xsl:for-each select="../event">
<xsl:if test=". = $this">
<xsl:value-of select="position()" />
</xsl:if>
</xsl:for-each>
</xsl:param>
<xsl:variable name="link">
<xsl:text>http://www.FreeBSD.org/news/newsflash.html#</xsl:text>
<xsl:call-template name="html-news-generate-anchor">
<xsl:with-param name="label" select="'event'" />
<xsl:with-param name="year" select="$year" />
<xsl:with-param name="month" select="$month" />
<xsl:with-param name="day" select="$day" />
<xsl:with-param name="pos" select="$pos" />
</xsl:call-template>
</xsl:variable>
<item>
<xsl:choose>
<xsl:when test="count(child::title)">
<title><xsl:value-of select="normalize-space(title)"/></title>
<description><xsl:value-of select="normalize-space(p)"/></description>
</xsl:when>
<xsl:otherwise>
<title><xsl:value-of select="normalize-space(p)"/></title>
</xsl:otherwise>
</xsl:choose>
<link><xsl:value-of select="normalize-space($link)"/></link>
<guid><xsl:value-of select="normalize-space($link)"/></guid>
<pubDate>
<xsl:call-template name="misc-format-date-string">
<xsl:with-param name="year" select="$year" />
<xsl:with-param name="month" select="$month" />
<xsl:with-param name="day" select="$day" />
<xsl:with-param name="date-format" select="$param-l10n-date-format-rfc822" />
</xsl:call-template>
</pubDate>
</item>
</xsl:template>
<xsl:template match="name | date"/>
</xsl:stylesheet>
|
