sys/conf/ldscript.mips.octeon1


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

/* $FreeBSD$ */

ENTRY(_start)

PHDRS {
	text PT_LOAD FLAGS(0x7);
}

SECTIONS {
	. = KERNLOADADDR + SIZEOF_HEADERS;

	.text : {
		*(.text)
		etext = .;
		_etext = .;
		. = ALIGN(0x2000);
	} : text

	. = ALIGN(0x2000);
	.rodata : {
		_fdata = .;
	    	*(.rodata)
		. = ALIGN(32);
	}

	.note.gnu.build-id : {
		PROVIDE (__build_id_start = .);
		*(.note.gnu.build-id)
		PROVIDE (__build_id_end = .);
	}
	
	.data : {
                _rwdata = .;
	    	*(.data)
		. = ALIGN(32);
	}
	.plt : { *(.plt) }
	_gp = ALIGN(16) + 0x7ff0;
	.got : { *(.got.plt) *(.got) }
	.dynamic : { *(.dynamic) }

	.sdata : {
                _small_start = .;
		*(.sdata)
		. = ALIGN(32);
		edata = .;
		_edata = .;
	} : text

	.sbss : {
		__bss_start = .;
		_fbss = .;
		*(.sbss) *(.scommon)
                _small_end = .;
		. = ALIGN(32);
	}

	.bss : {
		*(.bss)
		*(COMMON)
		. = ALIGN(32);
		_end = .;
		end = .;
	}

}